Indhold

# Tekstfunktioner

Denne sektion indeholder beskrivelser af Tekst-funktionerne.

For at tilgå denne kommando...

Indsæt - Funktion - Kategori Tekst

## Brug af dobbelte anførselstegn i formler

For at medtage en tekststreng i en formel placerer du tekststrengen mellem to dobbelte anførselstegn (") og Calc tager tegnene i strengen uden at prøve at fortolke dem. Formlen ="Hello world!" viser for eksempel tekststrengen Hello world! i cellen uden nogen omgivende dobbelte anførselstegn.

Den mere komplekse formel =SAMMENKÆDNING("Livet er rigtig simpelt, "; "men vi insisterer på at gøre det kompliceret "; "(Konfutse).") sammenkæder tre enkeltstrenge i dobbelte anførselstegn med resultatet "Livet er rigtig simpelt, men vi insisterer på at gøre det kompliceret (Konfutse).

For at placere et bogstaveligt dobbelt anførselstegn i en streng inde i en formel kan du bruge to fremgangsmåder:

1. Du kan "undvige" det dobbelte anførselstegn med et ydeligere dobbelt anførselstegn og Calc behandler det undvegne dobbelte anførselstegn som bogstavelig værdi. For eksempel giver formlen="Mit navn er ""Jens Hansen""." som resultat strengen Mit navn er "Jens Hansen". Et andet enkelt eksempel er formlen =UNICODE(""""), som returnerer 34, decimalværdien af Unicode anførselstegnet (U+0022) – her viser det det første og det fjerde dobbelte anførselstegn begyndelsen og slutningen af strengen, mens det andet dobbelte anførselstegn beskytter det tredje.

2. Du kan bruge funktionen TEGN eller funktionen UNICHAR til at indsætte et dobbelte anførselstegn. For eksempel viser formlen strengen=UNICHAR(34) & "Forbandede ungdom" & UNICHAR(34) & " er en berømt bog af J. D. Salinger." displays the string "Forbandede ungdom" er en berømt bog af J. D. Salinger.

Vær opmærksom på, at Calcs autokorrektur-funktion kan ændre dobbeltcitationstegn. Autokorrekt bør ikke ændre dobbeltcitationstegn i formelceller, men kan ændre dem som bruges ikke ikke-formelceller som indeholder tekst. Hvis du for eksempel kopierer en streng som er omgivet af en anden form for typografiske dobbeltcitationstegn, såsom venstre-dobbeltcitationstegn (U+201C) og højre-dobbeltcitationstegn (U+201D), og så sætter ind i en formelcelle, kan det resultere i en fejl. Brug området Dobbeltcitationstegn i dialogen Funktioner ▸ Autokorreturindstillinger ▸ Sprogindstillinger for at indstille hvilke tegn der bruges til autokorrektur af dobbelte start- og slut-citationstegn. Fjern kryds i Erstat-knappen for at deaktivere funktionen.

## ARABERTAL

Returnerer den numeriske værdi svarende til et romertal udtrykt som tekst.

## ASC

Konverterer dobbelt-byte (fuldbredde) tegn to enkelt-byte (halvbredde) ASCII- og katakana-tegn.

## JIS

Konverterer enkelt-byte (halv-bredde) ASCII- eller katakana-tegn til dobbelt-byte (fuld-bredde) tegn.

## REGEX-funktion

Matcher og udtrækker eller erstatter efter tilvalg tekst med regulære udtryk.

## ROMERTAL

Konverterer et tal til et romertal. Værdiområdet skal være mellem 0 og 3999. En forsimplet tilstand kan angives i området fra 0 til 4.

## VÆRDI

Konverterer strengrepræsentationen af et tal til numerisk form. Hvis den opgivne streng er en gyldig dato, klokkeslæt eller dato-klokkeslæt, returneres det serielle dato-klokkeslæt tal.

### WEBSERVICE

Hent web-indhold fra en URI.

### FILTERXML

Tilknytter et XPath-udtryk til et XML-dokument.

### ENCODEURL

Returnerer en URL-kodet streng.

## BAHTTEKST

Konverterer et tal til Thaitekst, inklusive Thaivalutanavne.

#### Syntaks

BAHTTEKST(Tal)

Tal er vilkårligt tal. "Baht" bliver føjet til den hele del af tallet, og "Satang" bliver føjet til decimaldelen af tallet.

#### Eksempel

=BAHTTEKST(12,65) returnerer en streng i Thaitegn med betydningen "Tolv Baht og femogtres Satang".

#### Tekniske oplysninger

Denne funktion er ikke en del af standarden Open Document Format for kontorprogrammer (OpenDocument) Version 1.3. del 4: Omregnet formel (OpenFormula) -format. Navnerummet er

COM.MICROSOFT.BAHTTEXT

## BASIS (BASE på engelsk)

Konverterer et positivt heltal til en angivet base til en tekst i nummereringssystemet. Cifrene 0-9 og bogstaverne A-Z bruges.

#### Syntaks

BASIS(Tal; Grundtal [; Minimumslængde])

Tal er det positive heltal, der skal konverteres.

Grundtal angiver grundtallet for talsystemet (f.eks. 10-talssystem). Det kan være et positivt heltal fra 2 til 36.

Minimumslængde (valgfri) bestemmer minimumslængden af tegnsekvensen, der er blevet oprettet. Hvis teksten er kortere end den indikerede minimumslængde, bliver nuller tilføjet til venstre for strengen.

#### Eksempel

=BASIS(17; 10; 4) returnerer 0017 i det decimale talsystem (titalssystemet).

=BASIS(17; 2) returnerer 10001 i det binære talsystem.

=BASIS(255; 16; 4) returnerer 00FF i det hexadecimale talsystem.

#### Se også

DECIMAL

## DECIMAL

Konverterer tekst som repræsenterer et tal i et talsystem med det angivne grundtal, til et positivt heltal. Grundtallet skal være i området 2 til 36. Mellemrum og tabulatorer ignoreres. Tekst-feltet skelner ikke mellem store og små bogstaver.

Hvis grundtallet er 16 (hexadecimalt tal) ignoreres et indledende x eller X eller 0X. Hvis grundtallet er 2 (binært tal) ignoreres et tilføjet b eller B. Andre tegn som ikke hører til talsystemet, resulterer i en fejl.

#### Syntaks

DECIMAL("Tekst"; Grundtal)

Tekst er teksten som skal konverteres.

Grundtal angiver talsystemets grundtal. Det kan være alle positive heltal fra 2 til 36.

#### Eksempel

=DECIMAL("17"; 10) returnerer 17.

=DECIMAL("FACE"; 16) returnerer 64206.

=DECIMAL("0101"; 2) returnerer 5.

#### Se også

BASIS

## EKSAKT (EXACT på engelsk)

Sammenligner to tekststrenge og returnerer SAND hvis de er identiske. Denne funktion skelner mellem store og små bogstaver.

#### Syntaks

EKSAKT("Tekst1"; "Tekst2")

Tekst1 refererer til den første tekst, der skal sammenlignes.

Tekst2 refererer til den anden tekst, der skal sammenlignes.

#### Eksempel

=EKSAKT("microsystems"; "Microsystems") returnerer FALSK.

## ERSTAT (REPLACE på engelsk)

Erstatter en del af en tekststreng med en anden tekststreng. Denne funktion kan bruges til at erstatte både tegn og tal (som automatisk bliver konverteret til tekst). Resultatet for funktionen er altid vist som tekst. Hvis du tilsigter at udføre videre beregninger med tal som er blevet erstattet af tekst, skal du konvertere den tilbage til et tal ved hjælp af VÆRDI funktionen.

Hvilken som helst tekst som indeholder tal skal være omgivet af anførselstegn hvis du ikke ønsker det skal fortolkes som et tal men automatisk betragtes som tekst.

#### Syntaks

ERSTAT("Tekst"; Placering; Længde; "NyTekst")

Tekst henviser til den tekst hvoraf en del skal erstattes.

Placering henviser til placeringen indeni teksten hvor erstatningen vil begynde.

Længde er antal tegn i Tekst som skal erstattes.

NyTekst refererer til teksten som erstatter Tekst.

#### Eksempel

ERSTAT("1234567"; 1; 1; "444") returnerer "444234567". Et tegn på placeringen 1 er erstattet af den fuldstændige NyTekst

## FAST (FIXED på engelsk)

Returnerer et som tekst med et angivet antal decimalpladser og valgfrie tusindtalskilletegn

#### Syntaks

FAST(Tal; [Decimaler = 2 [; NoThousandsSeparators = FALSE (Ingen Tusindtalssskilletegn = falsk )]])

Talafrundes til Decimal-pladser (efter decimalskilletegnet) og resultatet formateret som tekst, med lokationspecifikke indstillinger.

Decimals (decimaler) (valgfrie) henviser til antallet af decimalpladser, der skal vises. Hvis Decimals er negative, afrundes Number (tallet) til ABS(Decimals) (absolute decimaler) til venstre for decimaltegnet. Hvis Decimals er en brøk, afkortes og ignorerer faktisk, hvad der er den nærmeste heltal.

NoThousandsSeparators (Ingen tusindtalsskilletegn) (valgfri) bestemmer, om der skal bruges tusindtalsskilletegn. Hvis det er TRUE (sandt) eller ikke-nul, udelades gruppe-skilletegnene fra den resulterende streng. Hvis parameteren er lig med 0 eller hvis den mangler helt, vises tusindtalsskilletegnene i din aktuelle lokaliserings indstillinger.

#### Eksempel

=FAST(1234567,89;3) returnerer 1.234.567,890 som et tekststreng.

=FAST(123456,789;;TRUE) returnerer 123456,79 som en tekststreng.

=FAST(12345,6789;-2) returnerer 12,300 som en tekststreng.

=FAST(12134567,89;-3;1) returnerer 12135000som en tekststreng.

=FAST(12345,789;3/4) returnerer 12.346 som en tekststreng.

=FAST(12345.789;8/5) returnerer 12.345,8 som en tekststreng.

## FIND

Returnerer positionen på en tekststreng i en anden streng. Du kan også definere hvor søgningen skal begynde. Søgeordet kan være et tal eller en vilkårlig streng af tegn. Søgningen skelner mellem store og små bogstaver.

#### Syntaks

FIND("Find tekst"; "Tekst" [; Position])

FindTekst refererer til teksten, der skal findes.

Tekst er teksten, hvori søgningen finder sted.

Placering (valgfri) er positionen i teksten hvorfra søgningen starter.

#### Eksempel

=FIND(76; 998877665544) returnerer 6.

## GENTAG (REPT på engelsk)

Gentager en tekststreng i et givet antal kopier.

#### Syntaks

GENTAG("Tekst"; Antal)

Tekst er den tekst, der skal gentages.

Antal er antallet af gentagelser.

#### Eksempel

=GENTAG("God morgen";2) returnerer God morgenGod morgen.

Se flere detaljer om denne funktion på wiki-siden GENTAG (på engelsk: REPT).

## HØJRE (på engelsk: RIGHT)

Returnerer tegnene længst til højre i en tekst.

#### Syntaks

HØJRE( "Tekst" [; Antal])

Tekst er teksten hvor den højre del skal findes.

Antal (valgfri) er antallet af tegn fra den højre del af teksten. Hvis denne parameter ikke er defineret, returneres et tegn.

#### Eksempel

=HØJRE("Sun"; 2) returnerer un.

## HØJREB

Returnerer det/de sidste tegn i en tekst med double bytes characters sets (DBCS).

Denne funktion er tilgængelig siden LibreOffice 4.2.

#### Syntaks

HØJREB("Tekst" [; Antal_bytes])

Tekst er den tekst hvoraf den højre del skal bestemmes.

Antal_bytes (valgfri) angiver antallet af tegn, du vil have HØJREB til at udtrække, baseret på bytes. Hvis denne parameter ikke er defineret, returneres en byte.

#### Eksempel

HØJREB("中国";1) returnerer " " (1 byte er kun et halvt DBCS tegn og derfor returneres et blanktegn).

HØJREB("中国";2) returnerer "国" (2 bytes udgør et helt DBCS tegn).

HØJREB("中国";3) returnerer " 国" (3 bytes udgør ½ DBCS tegn og et helt DBCS tegn; et blanktegn returneres for det første halve tegn).

HØJREB("中国";4) returnerer "中国" (4 bytes udgør to fulde DBCS tegn).

HØJREB("office";3) returnerer "ice" (3 ikke-DBCS tegn hver bestående af 1 byte).

## KODE (CODE på engelsk)

Returnerer en numerisk kode for det første tegn i en tekst.

#### Syntaks

KODE("Tekst")

Tekst er teksten for hvilken koden for det første tegn skal findes.

Koder større end 127 kan afhænge af dit systems tegnsæt (for eksempel iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) og som følge der af ikke være kompatibel.

#### Eksempel

=KODE("Hieronymus") returnerer 72, =KODE("hieroglyfisk") returnerer 104.

Koden, der bruges her, refererer ikke til ASCII, men til den aktuelt indlæste kodetabel.

## KR (DOLLAR på engelsk)

Konverterer et tal til en streng som repræsenterer beløbet i valutaformatet, afrundet til et angivet antal decimaler, med brug af decimalskilletegnet som svarer til den nuværende lokalitetsindstilling. I Værdi-feltet skrives tallet, som skal konverteres. Du kan eventuelt angive antal decimaler i feltet Decimaler. Hvis der ikke angives antal decimaler, bliver tal i beløbsformatet vist med to decimaler.

Valutaformatet indstiller du i dine systemindstillinger.

#### Syntaks

KR(Værdi [; Decimaler])

Værdi er et tal, en reference til en celle med et tal, eller en formel, som returnerer et tal.

Decimaler er antallet af decimaler.

#### Eksempel

=KR(255) returnerer $255.00 for den engelske lokalisering (USA) og valutaen USD (dollar); ￥255.00 for den japanske lokalisering og valutaen JPY (yen); eller 255,00 € for den tyske lokalisering (Tyskland) og valutaen EUR (euro).

=KR(367,456;2) returnerer kr. 367,46.

## LÆNGDE (LEN på engelsk)

Returnerer længden af en streng inklusiv mellemrum.

#### Syntaks

LÆNGDE("Tekst")

Tekst er teksten hvis længde skal findes.

#### Eksempel

=LÆNGDE("God eftermiddag") returnerer 15.

=LÆNGDE(12345,67) returnerer 8.

## LÆNGDEB

For sprog med dobbeltbyte-tegnsæt (DBCS) returnerer denne funktion antallet af bytes, som benyttes til at repræsentere tegnene i en tekststreng.

Denne funktion er tilgængelig siden LibreOffice 4.2.

#### Syntaks

LÆNGDEB("Tekst")

Tekst er teksten hvis længde skal findes.

#### Eksempel

LÆNGDEB("中") returnerer 2 (et DBCS tegn består af 2 bytes).

LÆNGDEB("中国") returnerer 4 (to DBCS tegn hver på 2 bytes).

LÆNGDEB("office") returnerer 6 (seks ikke-DBCS tegn hver på 1 byte).

=LÆNGDEB("God eftermiddag") returnerer 15.

=LÆNGDEB(12345,67) returnerer 8.

## MIDT

Returnerer en del af en tekststreng. Parametrene angiver startpositionen og antal tegn.

#### Syntaks

MIDT("Tekst"; StartVed; Antal)

Tekst er den tekst som indeholder tegnene der skal findes.

StartVed er placeringen af det første tegn i kildeteksten der skal findes.

Antal angiver antal tegn der skal findes i teksten.

#### Eksempel

=MIDT("office";2;2) returnerer ff.

## MIDTB

Returnerer en tekststreng fra en DBCS-tekst (tekst med dobbeltbyte-tegnsæt). Parametrene angiver startpositionen og antallet af tegn.

Denne funktion er tilgængelig siden LibreOffice 4.2.

#### Syntaks

MIDB("Tekst"; StartVed; Antal_bytes)

Tekst er den tekst som indeholder tegnene der skal findes.

Start er positionen for det første tegn i den tekst du vil uddrage.

Antal_bytes angiver det antal tegn MIDB vil returnere fra tekst, i bytes.

#### Eksempel

=MIDB("中国";1;0) returnerer "" (0 bytes er altid en tom streng).

=MIDB("中国";1;1) returnerer " " (1 byte er kun et halvt DBCS-tegn og derfor er resultatet et mellemrumstegn).

=MIDTB("中国";1;2) returne "中" (2 bytes udgør et fuldstændigt DBCS-tegn).

=MIDTB("中国";1;3) returner "中 " (3 bytes udgør halvandet DBCS-tegn; den sidste byte resulterer i et mellemrumstegn).

=MIDTB("中国";1;4) returnerer "中国" (4 bytes udgør to fuldstændige DBCS-tegn).

=MIDTB("中国";2;1) returnerer " " (byteposition 2 er ikke i begyndelsen af en DBCS-streng; der returneres 1 mellemrumstegn).

=MIDTB("中国";2;2) returnerer " " (byteposition 2 peger på den sidste halvdel af det første tegn i DBCS-strengen; de 2 bytes, der bliver spurgt efter, udgør derfor den sidste halvdel af det første tegn og den første halvdel af det andet tegn i strengen; derfor returneres der 2 mellemrumstegn).

=MIDTB("中国";2;3) returnerer " 国" (byteposition 2 er ikke i begyndelsen på et tegn i en DBCS-streng; der returneres et mellemrumstegn for byteposition 2).

=MIDTB("中国";3;1) returnerer " " (byteposition 3 er ved begyndelsen af et tegn i en DBCS-streng, men 1 byte er kun et halvt DBCS-tegn og derfor returneres der et mellemstegn i stedet).

=MIDTB("中国";3;2) returnerer "国" (byteposition 3 er ved begyndelsen af et tegn i en DBCS-streng og 2 bytes udgør udgør et DBCS-tegn).

=MIDTB("office";2;3) returnerer "ffi" (byteposition 2 er ved begyndelsen af et tegn i en ikke-DBCS-streng og 3 bytes af en ikke-DBCS-streng udgør 3 tegn).

## RENS (CLEAN på engelsk)

Alle kontroltegn fjernes fra strengen.

#### Syntaks

RENS("Tekst")

Tekst refererer til teksten, hvorfra alle tegn der ikke kan udskrives fjernes.

#### Eksempel

=LÆNGDE(RENS(TEGN(7) & "LibreOffice Calc" & TEGN(8))) returnerer 16 og viser, at funktionen RENS fjerner de ikke-udskrivelige tegn Unicode U+0007 ("BEL") og U+0008 ("BS") i begyndelsen og slutningen af streng-argumentet. RENS fjerner ikke mellemrum.

## SAMMENKÆDNING (CONCATENATE på engelsk)

Kombinerer flere tekststrenge til i én streng.

#### Syntaks

SAMMENKÆDNING(Streng 1 [; Streng 2 [; … [; Streng 255]]])

Streng 1[; Streng 2][; … ;[Streng 255]] er strenge eller referencer til celler, der indeholder strenge.

#### Eksempel

=SAMMENKÆDNING("Godmorgen "; "Fr. "; "Jensen") returnerer: Godmorgen Fr. Jensen.

## SMÅ.BOGSTAVER (LOWER på engelsk)

Konverterer alle store bogstaver i en tekststreng til små bogstaver.

#### Syntaks

SMÅ.BOGSTAVER("Tekst")

Tekst refererer til den tekst, der skal konverteres.

#### Eksempel

=SMÅ.BOGSTAVER("Sol") returnerer sol.

## STORE.BOGSTAVER (UPPER på engelsk)

Konverterer strengen angivet i feltet Tekst til store bogstaver.

#### Syntaks

STORE.BOGSTAVER("Tekst")

Tekst henviser til den tekst med små bogstaver du vil konvertere til store bogstaver.

#### Eksempel

=STORE.BOGSTAVER("God morgen") returnerer GOD MORGEN.

## STORT.FORBOGSTAV (PROPER på engelsk)

Konverterer første bogstav i alle ord til stort bogstav i en tekststreng.

#### Syntaks

STORT.FORBOGSTAV("Tekst")

Tekst refererer til den tekst, der skal konverteres.

#### Eksempel

=STORT.FORBOGSTAV("the document foundation") returnerer The Document Foundation.

## SØG (SEARCH på engelsk)

Returnerer placeringen af et tekstsegment indenfor en tekststreng. Du kan sætte starten på søgningen som en mulighed. Søgeteksten kan være et tal eller en sekvens af tegn. Søgningen gør ikke forskel på store og små bogstaver. Hvis teksten ikke bliver fundet, returneres fejl 519 (#VALUE).

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ Præferencer Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konveretres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til lokalisering, hvor decimaltegnet ikke er punktum, kommer konverteringen fungere. For at gennemtvingen evalueringen af det regulære udtryk frem for et numerisk udtryk bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

#### Syntaks

SØG( "Find_tekst"; "Tekst" [; Position])

FindTekst er den tekst, der skal søges efter.

Tekst er teksten der skal søges i.

Placering (valgfri) er den placering i teksten hvor søgningen skal starte.

#### Eksempel

=SØG(54; 998877665544) returnerer 10.

## T

Denne funktion returnerer målteksten eller en tom tekststreng, hvis målet ikke er en tekst.

#### Syntaks

T(Værdi)

Hvis Værdi er en tekststreng eller refererer til en tekststreng, returnerer T denne tekststreng; ellers returnerer den en tom tekststreng.

#### Eksempel

=T(12345) returnerer en tom streng "".

=T("12345") returnerer strengen 12345.

## TEGN (CHAR på engelsk)

Konverterer et tal til et tegn ifølge den aktuelle kodetabel. Tallet kan være et to- eller trecifret heltal.

Koder større end 127 kan afhænge af dit systems tegnsæt (for eksempel iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) og som følge der af ikke være kompatibel.

#### Syntaks

TEGN(Tal)

Tal er et heltal mellem 1 og 255, som repræsenterer tegnets talværdi.

#### Eksempel

TEGN(100) returnerer tegnet d.

="abc" & TEGN(10) & "def" indsætter et linjeskiftskontroltegn ind i strengen.

## TEKST (TEXT på engelsk)

Konverterer en værdi til tekst i overensstemmelse med et givet format.

#### Syntaks

TEKST(Værdi; Format)

Værdi er den værdi (numerisk eller tekstlig), der skal konverteres.

Format er teksten som angiver formatet. Brug decimal og tusindtalsskilletegn ifølge sprogindstillingen i cellens formater.

#### Eksempel

=TEKST(12,34567;"###,##") returnerer teksten 12,35

=TEKST(12,34567;"000,00")returnerer teksten 012,35

=TEKST("xyz";"=== @ ===") returnerer teksten === xyz ===

Se også Nummerformat koder: tilpassede formatkoder defineret af brugeren.

## TRIM

Fjerner mellemrum fra en streng og efterlader kun et enkelt mellemrumstegn mellem ord.

#### Syntaks

TRIM("Tekst")

Tekst henviser til teksten hvor mellemrum vil blive fjernet.

#### Eksempel

=TRIM(" hej verden ") returnerer hej verden uden indledende og efterfølgende mellemrum, og med et enkelt mellemrum mellem ordene.

## UDSKIFT (SUBSTITUTE på engelsk)

Udskifter delord i en tekst.

#### Syntaks

UDSKIFT( "Tekst"; "Søgetekst"; "Ny tekst" [; Forekomst])

Tekst er teksten hvor tekstsegmentet skal udskiftes.

SøgTekst er tekstsegmentet som skal erstattes (et antal gange).

NyTekst er teksten som skal erstatte tekstsegmentet.

Forekomst (valgfri) angiver hvilken forekomst af søgeteksten, der skal erstattes. Hvis denne parameter mangler, erstattes alle forekomster.

#### Eksempel

=UDSKIFT("123123123";"3";"abc") returnerer 12abc12abc12abc

=UDSKIFT("123123123";"3";"abc";2) returnerer 12312abc123

## UNICHAR

Konverterer et kodetal til et Unicode-tegn eller -bogstav.

#### Syntaks

UNICHAR(nummer)

#### Eksempel

=UNICHAR(169) returnerer copyrighttegnet ©.

Se også UNICODE() funktionen.

## UNICODE

Returnerer den numeriske kode for det første Unicodetegn i en tekststreng.

#### Syntaks

UNICODE("Tekst")

#### Eksempel

=UNICODE("©") returnerer unicodeværdien 169 for copyrighttegnet.

Se også UNICHAR() funktionen.

## VENSTRE (LEFT på engelsk)

Returnerer det eller de første tegn i en tekststreng.

#### Syntaks

VENSTRE("Tekst" [; Tal])

Tekst er teksten, hvor de første tegn skal findes.

Antal (valgfri) specificerer antal tegn i begyndelsen af teksten. Hvis denne parameter ikke er angivet, returneres ét tegn.

#### Eksempel

=VENSTRE("resultat"; 3) returnerer "res".

## VENSTREB

Returnerer de første tegn af en DBCS-tekst.

Denne funktion er tilgængelig siden LibreOffice 4.2.

#### Syntaks

VENSTREB("Tekst" [; Antal_bytes])

Tekst er teksten, hvorfra de første tegn skal findes.

Antal_bytes (valgfri) angiver det antal tegn, som du ønsker LEFTB skal udtage, baseret på bytes. Hvis denne parameter ikke er defineret, returneres et enkelt tegn.

#### Eksempel

=VENSTREB ("中国";1) returner " " (1 byte er kun et halvt DBCS-tegn og der returneres et mellemrumstegn i stedet).

=VENSTREB("中国";2) returnerer "中" (2 bytes udgår et fuldstændigt DBCS-tegn).

=VENSTREB("中国";3) returnerer "中 " (3 bytes udgør halvandet DBCS-tegn; det sidste returnerede tegn er derfor et mellemrumstegn).

=VENSTREB("中国";4) returnerer "中国" (4 bytes udgør to fuldstændige DBCS-tegn).

=VENSTREB("office";3) returnerer "off" (3 ikke-DBCS-tegn, hvert bestående af 1 byte).

Relaterede emner

Funktioner efter kategori